home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 1, No. 11 (1982-07)(Softdisk)(Side A).zip / Softdisk Magazette Volume 1, No. 11 (1982-07)(Softdisk)(Side A).do / QUIZZER.bas < prev    next >
BASIC Source File  |  1996-12-24  |  4KB  |  66 lines
  1. 10  REM - QUIZZER PROGRAM
  2. 20  REM - BY SANDY SMITH
  3. 30  REM - 25 MAY 1982
  4. 40  REM - USES TEXT FILES
  5. 50  REM - CREATED BY THE
  6. 60  REM - 'QUIZ MAKER' PROGRAM
  7. 70  REM -------------------------
  8. 100 IN$ = "X":D$ =  CHR$(4):G$ =  CHR$(7):SC = 0
  9. 110  FOR J = 768 TO 788: READ I: POKE J,I: NEXT J
  10. 120  DATA 162,0,32,117,253,160,2,138,145,105,200,169,0,145,105,200,169,2,145,105,96
  11. 140  READ T: DIM QT$(T): FOR I = 1 TO T: READ QT$(I): NEXT I
  12. 150  REM DATA- FIRST # IS NUMBER OF QUIZZES ON DISK THEN LIST OF QUIZ TITLES
  13. 160  DATA 3
  14. 170  DATA AMERICAN AVERAGES,ELEGANT EATING,PIQUANT PEOPLE
  15. 300  REM  MENU
  16. 310  TEXT : HOME : HTAB 15: PRINT "-- QUIZZER --": PRINT : HTAB 15: PRINT "BY SANDY SMITH"
  17. 320  PRINT : PRINT "QUIZZES AVAILABLE:": PRINT : FOR I = 1 TO T: PRINT I;". ";QT$(I): NEXT I
  18. 330  PRINT : PRINT "TYPE THE NUMBER OF YOUR CHOICE OR ": INVERSE : PRINT "ESC";: NORMAL : PRINT " TO QUIT: ";: GET OK$: IF OK$ =  CHR$(27)  THEN  PRINT  CHR$(4): PRINT  CHR$(4);"RUN KICK.IT.OFF"
  19. 340  PRINT OK$:OK =  VAL(OK$): IF OK <1  OR OK >T  THEN  PRINT G$: GOTO 330
  20. 350  HOME : VTAB 12: INVERSE : PRINT " PLEASE WAIT FOR THE QUIZ TO BE CREATED ": NORMAL 
  21. 400  REM READ FROM DISK
  22. 410 IN$ = " ": PRINT D$;"OPEN ";QT$(OK): PRINT D$;"READ ";QT$(OK)
  23. 420  INPUT N: DIM Q$(N),AA$(N),AB$(N),AC$(N),AD$(N),CA$(N)
  24. 430  FOR I = 1 TO N: GOSUB 450:Q$(I) = IN$: GOSUB 450:AA$(I) = IN$: GOSUB 450:AB$(I) = IN$: GOSUB 450:AC$(I) = IN$: GOSUB 450:AD$(I) = IN$
  25. 440  INPUT CA$(I): NEXT I: PRINT D$;"CLOSE ";QT$(OK): GOTO 510
  26. 450  CALL 768:IN$ =  MID$ (IN$,1): RETURN 
  27. 500  REM QUIZ
  28. 510  FOR I = 1 TO N
  29. 520  HOME : HTAB 20 - INT( LEN(QT$(OK))/2): INVERSE : PRINT QT$(OK): VTAB 3: PRINT "QUESTION #";I;" ": NORMAL 
  30. 530  VTAB 5: PRINT Q$(I): PRINT : PRINT "A. ";AA$(I): PRINT "B. ";AB$(I): PRINT "C. ";AC$(I): PRINT "D. ";AD$(I): PRINT 
  31. 540  HTAB 4: INPUT "WHAT IS THE BEST CHOICE? ";AN$: IF AN$ < >"A"  AND AN$ < >"B"  AND AN$ < >"C"  AND AN$ < >"D"  THEN  PRINT G$: GOTO 540
  32. 550  IF AN$ < >CA$(I)  THEN 570
  33. 560 SC = SC +1: VTAB 20: PRINT "CORRECT!": PRINT : INVERSE : PRINT "SCORE:";: NORMAL : PRINT " ";SC;" OUT OF ";I: GOTO 580
  34. 570  VTAB 20: PRINT G$;"THE RIGHT ANSWER WAS ";: INVERSE : PRINT CA$(I): PRINT : PRINT "SCORE:";: NORMAL : PRINT " ";SC;" OUT OF ";I
  35. 580  VTAB 24: HTAB 5: PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : INPUT " TO CONTINUE...";OK$: IF OK$ < >""  THEN  PRINT G$: GOTO 580
  36. 590  NEXT I
  37. 600  REM TOTAL SCORE
  38. 610  HOME : HTAB 20 - INT( LEN(QT$(OK))/2): PRINT QT$(OK): VTAB 6: INVERSE : PRINT "FINAL SCORE:";: NORMAL : PRINT " ";SC;" RIGHT OUT OF ";N;"."
  39. 620  IF SC = N  THEN  PRINT : PRINT "THAT WAS PERFECT!!!": GOTO 710
  40. 630 P =  INT((SC/N) *100 +.5)
  41. 640  IF P =  >94  THEN  PRINT : PRINT "THAT WAS EXCELLENT!!": GOTO 710
  42. 650  IF P =  >84  THEN  PRINT : PRINT "THAT WAS VERY GOOD!": GOTO 710
  43. 660  IF P =  >74  THEN  PRINT : PRINT "THAT WAS GOOD": GOTO 710
  44. 670  IF P =  >70  THEN  PRINT : PRINT "THAT WAS FAIR.": GOTO 710
  45. 680  IF P =  >50  THEN  PRINT : PRINT "THAT WAS POOR.": GOTO 710
  46. 690  PRINT : PRINT "THAT WAS VERY POOR."
  47. 700  REM GO BACK TO MENU
  48. 710  VTAB 24: HTAB 5: PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : INPUT " TO CONTINUE...";OK$: IF OK$ < >""  THEN  PRINT G$: GOTO 710
  49. 720  CLEAR : GOTO 100
  50. 65535  REM ----------------------
  51. 65535  REM - QUIZZER PROGRAM
  52. 65535  REM - BY SANDY SMITH
  53. 65535  REM - 25 MAY 1982
  54. 65535  REM - MULTIPLE-CHOICE
  55. 65535  REM - QUIZZES ARE IN
  56. 65535  REM - TEXT FILES
  57. 65535  REM - CREATED BY THE
  58. 65535  REM - 'QUIZ MAKER' PROGRAM
  59. 65535  REM ----------------------
  60. 65535  REM - ORIGINAL PROGRAM
  61. 65535  REM - IDEA CAME FROM
  62. 65535  REM - PATRICIA SINE'S
  63. 65535  REM - MIDDLE.AGES.QUIZ
  64. 65535  REM - SOFTDISK MAGAZETTE
  65. 65535  REM - MAY 1981
  66. 65535  REM ----------------------